Admin FAQ

public abstract class ExampleTriggerHandler {
    public virtual void beforeInsert(List<SObject> newRecords) {
    }
    public virtual void beforeUpdate(Map<Id, SObject> newRecordMap, Map<Id, SObject> oldRecordMap) {
    }
    public virtual void beforeDelete(Map<Id, SObject> oldRecordMap) {
    }
    public virtual void afterInsert(Map<Id, SObject> newRecordMap) {
    }
    public virtual void afterUpdate(Map<Id, SObject> newRecordMap, Map<Id, SObject> oldRecordMap) {
    }
    public virtual void afterDelete(Map<Id, SObject> oldRecordMap) {
    }
    public virtual void afterUndelete(Map<Id, SObject> newRecordMap) {
    }
}

public class ExampleUpdateRecordsAsync implements Queueable {
    private List<SObject> records;

    public ExampleUpdateRecordsAsync(List<SObject> records) {
        this.records = records;
    }

    public void execute(QueueableContext context) {
        if (this.records == null || this.records.isEmpty()) {
            return;
        }

        Database.update(this.records, false);
    }
}

public inherited sharing class ExampleAdditionalInfoTriggerHandler extends ExampleTriggerHandler {
    public override void afterUpdate(Map<Id, SObject> newMap, Map<Id, SObject> oldMap) {
        List<sumoapp__AdditionalInfo__c> sumoEventsWithUpdatedDescription = this.generateDescriptions(
            this.filterDraftSumoEvents(newMap)
        );

        if (!sumoEventsWithUpdatedDescription.isEmpty()) {
            System.enqueueJob(new ExampleUpdateRecordsAsync(sumoEventsWithUpdatedDescription));
        }
    }

    private List<sumoapp__AdditionalInfo__c> filterDraftSumoEvents(Map<Id, SObject> newMap) {
        List<sumoapp__AdditionalInfo__c> result = new List<sumoapp__AdditionalInfo__c>();

        for (sumoapp__AdditionalInfo__c item : (List<sumoapp__AdditionalInfo__c>) newMap.values()) {
            if (this.isDraftSumoEvent(item)) {
                result.add(item);
            }
        }

        return result;
    }

    private Boolean isDraftSumoEvent(sumoapp__AdditionalInfo__c item) {
        return item.sumoapp__IsDraft__c == true && item.sumoapp__Status__c != 'CANCELED' && String.isNotBlank(item.sumoapp__Description__c);
    }

    private List<sumoapp__AdditionalInfo__c> generateDescriptions(List<sumoapp__AdditionalInfo__c> sumoEvents) {
        List<sumoapp__AdditionalInfo__c> result = new List<sumoapp__AdditionalInfo__c>();
        sumoapp__AdditionalInfo__c sumoEvent;
        for (sumoapp__AdditionalInfo__c item : sumoEvents) {
            sumoEvent = new sumoapp__AdditionalInfo__c(
                Id = item.Id,
                sumoapp__IsDraft__c = false,
                sumoapp__Description__c = this.generateDescription(item)
            );

            result.add(sumoEvent);
        }

        return result;
    }

    private String generateDescription(sumoapp__AdditionalInfo__c item) {
        /**
         * Any field value or plain text to add to the current description
         */
        String customText = item.sumoapp__Source__c;

        return String.join(new List<String>{ item.sumoapp__Description__c, customText }, '<br/>');
    }
}

trigger ExampleAdditionalInfo on sumoapp__AdditionalInfo__c(after update) {
    ExampleTriggerHandler handler = new ExampleAdditionalInfoTriggerHandler();
    if (Trigger.operationType == TriggerOperation.AFTER_UPDATE) {
        handler.afterUpdate(Trigger.newMap, Trigger.oldMap);
    }
}